wget https://github.com/Shavian-info/readlex/raw/refs/heads/main/kingsleyreadlexicon.tsv

# வரிகளின் எண்ணிக்கை (நமக்கு 1650) fold.awk யில் குறிப்பிடப்பட்டுள்ள விதிக்குக்
# கட்டுப்பட்டிருக்க வேண்டும்.

# ஒரே எழுத்தாக்கமுடையச் சொற்களைச் சேர், சொல் நிகழ்வெண்படி வரிசைப்படுத்து, முதல்
# 1650 சொற்களை மட்டும் எடு, இலத்தீன் எழுத்தாக்கத்தையும் ஷேவியன் எழுத்தாக்கத்தையும்
# மட்டும் பெயர்த்தெடு, அகரவரிசைப்படுத்து, இறுதியில் நிரல்களை அச்சிடத்தக்க "மடி".
awk -f collapse.awk kingsleyreadlexicon.tsv | \
    sort -nrk 3,3 | head -n1650 \
    | cut -f1,2 | sort -k 1,1 \
    | awk -f fold.awk > shavian-1650.tsv

BEGIN {
    OFS = "\t"
}

{
    latin = $1
    shavian = $2
    frequency = $5
}

NR == 1 {
    # நிலைச் சேமி. வேறு எதுவும் செய்யற்க.
    previous_latin = latin
    previous_shavian = shavian
    accumulated_frequency = frequency
}

NR > 1 {
    # வேறுச் சொல்லாயின் வெளியிட்டு நிகழ்வெண் சேமிப்பை அழி.
    if ((latin != previous_latin) || (shavian != previous_shavian)) {
        print previous_latin, previous_shavian, accumulated_frequency
        accumulated_frequency = 0
    }
    # நிலைச் சேமி.
    accumulated_frequency += frequency
    previous_latin = latin
    previous_shavian = shavian
}

END {
    # இதுத் தான் இறுதி வரி; வரியை வெளியிடு.
    print previous_latin, previous_shavian, accumulated_frequency
}

# இந்த உரைநிரல் வரிகளின் எண்ணிக்கை lines_per_page * sections_per_page யின்
# பெருக்கமாகயிருப்பின் மட்டுமே சரியாக வேலை செய்யும். இது பக்கங்கள் முழுமையாக
# நிறைந்து வெற்றிடமில்லா நிலை.
BEGIN {
    lines_per_page = 55;
    sections_per_page = 3;
}

# வரிகளை அணியில் அடக்கு.
{
    page_line = (NR - 1) % (lines_per_page * sections_per_page)
    lines[page_line % lines_per_page, int(page_line / lines_per_page)] = $0
}

# பக்கம் முடிந்ததும் சேர்த்த அணியைக் கொட்டு. பின், அடுத்தப் பக்கத்தை உருவாக்க அணியை
# அழி.
(page_line == lines_per_page*sections_per_page - 1) {
    for (i=0; i<lines_per_page; i++) {
        for (j=0; j<sections_per_page; j++) {
            printf (j == 0) ? "%s" : "\t%s", lines[i, j]
            delete lines[i, j]
        }
        printf "\n"
    }
}